スタイルでフォントを指定する

タグによるフォントの指定は、テキストの一部だけフォントを変えるなどできて便利なのだが
長~いスクリプトで全体的にフォントを変えていこうと思った場合
毎度毎度textパラメータに長ったらしい記述をしなくてはいけないのは、すごく面倒だ。
そんな時に使うのが…

スタイル定義だ。

フォントの形、サイズ、色などを『スタイル』という形で予め定義しておき、
命令ではそのスタイルを指定して使う。
このようにすると命令毎のフォントの指定を大幅に簡略化できる。

HTMLを知ってる人なら「スタイルシートみたいなものかな?」
と思ったかもしれない。
記述の仕方はちょっと違うが、機能の意図としては同じようなものだ。

どう書くのか見ていこう。
まずはスタイルを定義する記述。


style 普通 { face="MS ゴシック", size=32 }

“普通”という名前のスタイルを定義している。
簡単なので詳しく説明しなくても、どういう意味の記述かだいたいわかると思う。

次にスタイルの使い方。
スタイルはFONTタグで指定できる。


  CreateBalloon(name="台詞1"
    , text="<FONT style='普通'>それにしても<BR>腹が減った</FONT>"
    , x=588, y=75, tail=-30);

しかしまだこれもちょっと煩雑なかんじだ。
文章全体にスタイルを指定してしまってかまわない場合は、もっと簡単に記述する方法がある。
それがCreateBalloon命令のstyleパラメータを使う方法。


  CreateBalloon(name="台詞1"
    , style="普通", text="それにしても<BR>腹が減った"
    , x=588, y=75, tail=-30);

かなりスッキリした!
それでは組み込んでみよう。


style 普通 { face="MS ゴシック", size=32 }
style 小 { size=24 }

method Main()
{
  CreateImage(name="背景", image="背景.png"
    , x=0, y=0);
  CreateFrame(name="コマ1", image="コマ1.png"
    , x=440, y=0, alpha=0%);
  CreateFrame(name="コマ2", image="コマ2.png"
    , x="OutRight", y=65);
  CreateFrame(name="コマ3", image="コマ3.png"
    , x=407, y=505, ox="Center", oy="Middle", sx=0%, sy=0%);
  CreateBalloon(name="台詞1"
    , style="普通", text="それにしても<BR>腹が減った"
    , x=588, y=75, tail=-30);
  CreateBalloon(name="台詞2"
    , style="小", text="クククク…"
    , x=485, y=525, tail=160);

  Enter(to="背景");
  wait 1000;

  Enter(to="コマ1");
  Opaque(to="コマ1", time=1000, alpha=100%);
  wait 1000;

  Enter(to="コマ2");
  Move(to="コマ2", time=1000, x=780);
  wait 1000;

  Enter(to="台詞1");
  wait 1500;

  Enter(to="コマ3");
  Zoom(to="コマ3", time=1000, sx=100%, sy=100%);
  wait 1000;

  Enter(to="台詞2");
  wait 1000;
}

実行結果は前回と一緒なので省略~


Leave a Reply

*