コマの枠を指定する

『漫画のコマ』に相当するフレームデーカーには、
画像に自動的に「枠」をつけてくれるという機能がある。
今まで画像の周りにぼやーっと黒い枠がついていたと思うが、ソレだ。

けれどもただ単に枠がつくだけにすぎないので…
「だったら最初から画像自体に枠をつけてしまえばいいんじゃないの？」
「わざわざフレームデーカーなんて使う必要ないんじゃないの？」
「イメージデーカーで十分なんじゃないの？」
と思うかもしれない。

実際のところ画像自体に枠をつけてしまっても良いのだが
フレームデーカーを使って枠をつけることによる利点がいくつかある。
画像からコマを切り出す作業をする際に、枠のことをいちいち考えなくてよくなることも大きいが
最大の利点は、枠の形をスクリプトで調整することができるという点だ。

枠を指定するにはCreateFrame命令の
outline_shape、outline_color、outline_thickパラメータを使う。

CreateFrame(name="コマ２", image="コマ２.png"
  , x="OutRight", y=65
  , outline_shape="Vivide", outline_color=white, outline_thick=8);

outline_shape パラメータには枠の種類の名前を指定する。
“Fade”,”Vivide”,”Shadow”,”Emboss”などいくつか種類がある。
outline_color パラメータには枠の色を指定する。
outline_thick パラメータには枠の太さを指定する。

では組み込んでみよう。

style 普通 { face="ＭＳ ゴシック", size=32 }
style 小 { size=24 }
style つぶやき { interval=100, speed=250, effect="Rise" }

method Main()
{
  CreateImage(name="背景", image="背景.png"
    , x=0, y=0);

  CreateFrame(name="コマ１", image="コマ１.png"
    , x=440, y=0, alpha=0%
    , outline_shape="Fade", outline_color=RGBA(0,0,0,64), outline_thick=8);
  CreateFrame(name="コマ２", image="コマ２.png"
    , x="OutRight", y=65
    , outline_shape="Vivide", outline_color=white, outline_thick=8);
  CreateFrame(name="コマ３", image="コマ３.png"
    , x=407, y=505, ox="Center", oy="Middle", sx=0%, sy=0%
    , outline_shape="Vivide", outline_color=black, outline_thick=8);

  CreateBalloon(name="台詞１"
    , style="普通", text="それにしても...<BR>腹(はら)が減(へ)った"
    , x=585, y=65, shape="Dumpling", w=300, h=185, tail=-30);
  CreateBalloon(name="台詞２"
    , style="小", text="<FONT style='つぶやき'>クククク…"
    , x=470, y=520, shape="Rock", w=220, h=125, tail=160);

  Enter(to="背景");
  wait 1000;

  Enter(to="コマ１");
  Opaque(to="コマ１", time=1000, alpha=100%);
  wait 1000;

  Enter(to="コマ２");
  Move(to="コマ２", time=1000, x=780);
  wait 1000;

  Enter(to="台詞１", effect="Bound");
  wait 2000;

  Enter(to="コマ３");
  Zoom(to="コマ３", time=1000, sx=100%, sy=100%);
  wait 1000;

  Enter(to="台詞２", effect="Expand");
  wait 1000;
}

枠を変えたことでまたガラッと雰囲気が変わった！