速度変化をつける

今度はコマの動きを工夫してみよう。
とはいえコマの動き方を大きく変えようという話ではない。
コマの動きに『速度変化』をつけようというお話だ。

今までコマが移動したり拡大したりしていたが、その動きその速度は常に一定だった。
よくよく考えてみると、現実において一定の速度で動くものというものはあまり目にしない。
一定速度で動くなんて自然ではない。不自然だ。
そのあたりが関係しているのかはよくわからないが…

確信を持ってこれだけは言える。

速度変化をつけるとキモチイイ

キモチイイ！
大事！

論より証拠。
実際に速度変化をつけてみよう。
動きに速度変化をつけるには step パラメータを使う。

Zoom(to="コマ３", time=1000, sx=100%, sy=100%, step="AccSig");

step パラメータは time パラメータをとる全ての命令で使うことができる。
step パラメータには速度変化の名前を指定する。
いくつか紹介しておこう。

Linear
AccSin
Acc2
Acc3
DecSin
Dec2
Dec3
AccSig

では実際に組み込んでみよう。

style 普通 { face="ＭＳ ゴシック", size=32 }
style 小 { size=24 }
style つぶやき { interval=100, speed=250, effect="Rise" }

method Main()
{
  CreateImage(name="背景", image="背景.png"
    , x=0, y=0);

  CreateFrame(name="コマ１", image="コマ１.png"
    , x=440, y=0, alpha=0%
    , outline_shape="Fade", outline_color=RGBA(0,0,0,64), outline_thick=8);
  CreateFrame(name="コマ２", image="コマ２.png"
    , x="OutRight", y=65
    , outline_shape="Vivide", outline_color=white, outline_thick=8);
  CreateFrame(name="コマ３", image="コマ３.png"
    , x=407, y=505, ox="Center", oy="Middle", sx=0%, sy=0%
    , outline_shape="Vivide", outline_color=black, outline_thick=8);

  CreateBalloon(name="台詞１"
    , style="普通", text="それにしても...<BR>腹(はら)が減(へ)った"
    , x=585, y=65, shape="Dumpling", w=300, h=185, tail=-30);
  CreateBalloon(name="台詞２"
    , style="小", text="<FONT style='つぶやき'>クククク…"
    , x=470, y=520, shape="Rock", w=220, h=125, tail=160);

  Enter(to="背景");
  wait 1000;

  Enter(to="コマ１");
  Opaque(to="コマ１", time=1000, alpha=100%, step="AccSin");
  wait 1000;

  Enter(to="コマ２");
  Move(to="コマ２", time=1000, x=780, step="Dec3");
  wait 1000;

  Enter(to="台詞１", effect="Bound");
  wait 2000;

  Enter(to="コマ３");
  Zoom(to="コマ３", time=1000, sx=100%, sy=100%, step="AccSig");
  wait 1000;

  Enter(to="台詞２", effect="Expand");
  wait 1000;
}

キモチイイ！