ルビを振る

タグについて説明したので、ついでにルビを振る方法についても説明しておこう。

ルビとは漢字の上や横に読み仮名を小さな文字で書くアレだ。
難しい単語の読みをわかりやすくるためや、
通常とはまったく異なった読み方をさせたい時などに主に使う。
・をルビにすることで文章を強調するなんて使い方もある。
少年漫画では、読者層を考慮して全ての漢字にルビを振っていることが多い。

単語にルビを振るにはRUBYタグを使う。

<RUBY text='さんま'>秋刀魚</RUBY>

これで”秋刀魚”に”さんま”とルビが振られる。
振り仮名にはひらがな、カタカナ、英数字、漢字を自由に使用できる。
振り仮名と単語の文字数は一緒でなくてもいい。

…しかしこの書きかたはなんとも大げさだ。
単語より前に振り仮名を書くというのも、ちょっと直感的ではない。

実はもっと簡単にルビを記述する方法がある。

(秋刀魚/さんま)

随分すっきりした。
文中において(～/～)という表記はルビの指定と解釈されRUBYタグと同様の効果がある。

さらにルビを振る対象が漢字だけで構成され、
見た目で対象範囲を特定できる場合はもっと簡単に記述できる。

秋刀魚(さんま)

超スッキリ！

ほとんどの場合、この書き方で事足りる。
実際に組み込んでみよう。

style 普通 { face="ＭＳ ゴシック", size=32 }
style 小 { size=24 }

method Main()
{
  CreateImage(name="背景", image="背景.png"
    , x=0, y=0);
  CreateFrame(name="コマ１", image="コマ１.png"
    , x=440, y=0, alpha=0%);
  CreateFrame(name="コマ２", image="コマ２.png"
    , x="OutRight", y=65);
  CreateFrame(name="コマ３", image="コマ３.png"
    , x=407, y=505, ox="Center", oy="Middle", sx=0%, sy=0%);
  CreateBalloon(name="台詞１"
    , style="普通", text="それにしても<BR>腹(はら)が減(へ)った"
    , x=588, y=75, tail=-30);
  CreateBalloon(name="台詞２"
    , style="小", text="クククク…"
    , x=485, y=525, tail=160);

  Enter(to="背景");
  wait 1000;

  Enter(to="コマ１");
  Opaque(to="コマ１", time=1000, alpha=100%);
  wait 1000;

  Enter(to="コマ２");
  Move(to="コマ２", time=1000, x=780);
  wait 1000;

  Enter(to="台詞１");
  wait 1500;

  Enter(to="コマ３");
  Zoom(to="コマ３", time=1000, sx=100%, sy=100%);
  wait 1000;

  Enter(to="台詞２");
  wait 1000;
}

修正点が少なすぎて拍子抜けしただろう。
このくらいルビは簡単に使用できるのだ。